&PL      PROC  &P,20                                                    WAI00010
WAITM    NAME  0                                                        WAI00020
.*       WAITM (1)                                                      WAI00030
.*                                                                      WAI00040
.*       OR                                                             WAI00050
.*                                                                      WAI00060
.*       WAITM LIST-ADDR                                                WAI00070
.*                                                                      WAI00080
.*       OR                                                             WAI00090
.*                                                                      WAI00100
.*       WAITM ECB,CCB,...                                              WAI00110
.*                                                                      WAI00120
.*       SUMMARY OF CODE GENERATED                                      WAI00130
.*                                                                      WAI00140
.*       NOTE: LABELS ARE NOT GENERATED BY THE MACRO. THE DISPLACEMENTS WAI00150
.*             TO THE LABELS ARE CALCULATED AND GENERATED BY THE MACRO. WAI00160
.*                                                                      WAI00170
.*       NUMBER OF BYTES GENERATED IS BETWEEN 18 AND                    WAI00180
.*       24+4(# OF PARAMETERS > 1)                                      WAI00190
.*                                                                      WAI00200
.*    1. (1) OR 1 INDICATES REGISTER 1 HAS BEEN PRELOADED WITH LIST     WAI00210
.*       ADDR.                                                          WAI00220
.*    2. ONE PARAMETER INDICATES THE SYMBOLIC NAME (ADDR) OF A LIST     WAI00230
.*       CONTAINING FULLWORD ADDRESSES OF ECB'S AND/OR CCB'S TO BE      WAI00240
.*       AWAITED                                                        WAI00250
.*    3. MORE THAN ONE PARAMETER REPRESENTS THE SYMBOLIC NAMES(ADDRS)   WAI00260
.*       OF THE ECB'S OR CCB'S TO BE AWAITED.                           WAI00270
.*                                                                      WAI00280
.*       &AA IS DEFINED AS &P(1)=(1) OR &P(1)=1                         WAI00290
.*                                                                      WAI00300
.*       &BB IS DEFINED AS &P(2)=BLANK   PARAMETER P(1) IS LIST         WAI00310
.*                                                                      WAI00320
.*       &CC  IS DEFINED AS &P(2) NOT EQUAL TO BLANK. PARAMETERS ARE    WAI00330
.*            LIST ELEMENTS.                                            WAI00340
.*                                                                      WAI00350
.*       CODE GENERATED                 CONDITIONS                      WAI00360
.*                                                                      WAI00370
.*       CNOP  2,4                      &BB OR &CC                      WAI00380
.*       L     R1,A                     &BB                             WAI00390
.*       SR    R0,R0                                                    WAI00400
.*       B     B                        &BB                             WAI00410
.*   A   DC    A(&P(1))                 &BB                             WAI00420
.*       BAL   R1,B                     &CC                             WAI00430
.*       DC    A(&P(1))                 &CC                             WAI00440
.*       DC    A(&P(2))                 &CC                             WAI00450
.*       ...                            &CC                             WAI00460
.*       DC    A(&P(N))                 &CC                             WAI00470
.*  B    SVC 12                                                         WAI00480
.*       LTR   0,0                                                      WAI00490
.*       BZ    *+6                                                      WAI00500
.*       SVC   28                                                       WAI00510
.*       LA    R0,1                                                     WAI00520
.*       SVC   12                                                       WAI00530
.*                                                                      WAI00540
.*       IF CONTENTS OF R0 IS ZERO, SVC 11 WILL AWAIT ELEMENTS IN THE   WAI00550
.*       LIST POINTED TO BY R1.                                         WAI00560
.*       IF CONTENTS OF R0 IS NON-ZERO, SVC 11 WILL CLEAR WAIT          WAI00570
.*       CONDITION FOR ELEMENTS OF LIST POINTED TO BY R1. UPON          WAI00580
.*       COMPLETION R1 WILL CONTAIN THE ADDRESS OF THE FIRST            WAI00590
.*       ELEMENT IN THE LIST THAT IS COMPLETED.                         WAI00600
.*                                                                      WAI00610
.*                                                                      WAI00620
         LCL   &AA,&BB,&CC,&X                                           WAI00630
&AA      SET   ('&P(1)'='(1)')++('&P(1)'='1')                           WAI00640
&BB      SET   ('&P(2)'='')*(&AA=0)                                     WAI00650
&CC      SET   ('&P(2)'='')=0                                           WAI00660
         DO    '&P(1)'=''                                               WAI00670
         PNOTE 'P','PARAMETER 1 MISSING'                                WAI00680
&BB      SET   1                                                        WAI00690
&CC      SET   0                                                        WAI00700
         ENDO                                                           WAI00710
.*                                                                      WAI00720
&X       SET   '&PL.        '(1,8)                                      WAI00730
&X           DS    0H                                                   WAI00740
                   CNOP  2,4                                            WAI00750
         DO    &AA                                                      WAI00760
                   O     1,*+10                                         WAI00770
         ENDO                                                           WAI00780
         DO    &BB                                                      WAI00790
                   L     1,*+10                                         WAI00800
         ENDO                                                           WAI00810
                   SR    0,0                                            WAI00820
         DO    &AA++&BB                                                 WAI00830
                   B     *+8                                            WAI00840
         ENDO                                                           WAI00850
         DO    &AA                                                      WAI00860
                   DC    XL4'80000000'                                  WAI00870
         ENDO                                                           WAI00880
         DO    &BB                                                      WAI00890
                   DC    AL1(X'80')                                     WAI00900
                   DC    AL3(&P(1))                                     WAI00910
         ENDO                                                           WAI00920
         DO    &CC                                                      WAI00930
&X       SET   N'&P                                                     WAI00940
                   BAL   1,*+4+(4*&X)                                   WAI00950
&Q       DO    N'&P                                                     WAI00960
                   DC    A(&P(&Q))                                      WAI00970
         ENDO                                                           WAI00980
         ENDO                                                           WAI00990
                   SVC   12                                             WAI01000
                   LTR   0,0            ERROR ?                         WAI01010
                   BZ    *+6                                            WAI01020
                   SVC   28             CANCEL                          WAI01030
                   LA    0,1                                            WAI01040
                   SVC   12                                             WAI01050
         END                                                            WAI01060
