&BLOCK   PROC  &P,0,&BLKSIZE=,&DEVICE=,&ENTRY=,&EOFADDR=,&FUNCTION=,   XQUE00010
               &TYPEFLE=,&DEST=,&LFD=,&CNTRL=,&VARIABLE=                QUE00020
QUE      NAME  QUE                                                      QUE00030
SG$QUE   NAME  SG$QUE                                                   QUE00040
LOCQUE   NAME  LOCQUE                                                   QUE00045
         GBL   &NT$BKSZ,&NT$DEV,&NT$NTRY,&NT$EOFA,&NT$FNCD              QUE00050
         GBL   &NT$TYPF,&NT$DEST,&NT$LFD,&NT$CTRL,&NT$VRBL              QUE00060
         LCL   &FLG                                                     QUE00070
.*                                                                      QUE00080
         DO    '&P(0)'='QUE'                                            QUE00090
&NT$BKSZ SET   '&BLKSIZE'                                               QUE00100
&NT$CTRL SET   '&CNTRL'                                                 QUE00110
&NT$DEST SET   '&DEST'                                                  QUE00120
&NT$DEV  SET   '&DEVICE'                                                QUE00130
&NT$FNCD SET   '&FUNCTION'                                              QUE00140
&NT$LFD  SET   '&LFD'                                                   QUE00150
&NT$TYPF SET   '&TYPEFLE'                                               QUE00160
&NT$NTRY SET   '&ENTRY'                                                 QUE00170
&NT$EOFA SET   '&EOFADDR'                                               QUE00180
&NT$VRBL SET   '&VARIABLE'                                              QUE00185
         ENDO                                                           QUE00190
.*                                                                      QUE00200
         DO    1-('&NT$NTRY'='')                                        QUE00210
         EXTRN &NT$NTRY                                                 QUE00220
         ENDO                                                           QUE00230
.*                                                                      QUE00240
         DO    1-('&NT$EOFA'='')                                        QUE00250
         EXTRN &NT$EOFA                                                 QUE00260
         ENDO                                                           QUE00270
.*                                                                      QUE00280
         CNOP  0,4                                                      QUE00290
         DO    1-('&BLOCK'='')                                          QUE00300
         ENTRY &BLOCK                                                   QUE00310
&BLOCK   EQU   *                                                        QUE00320
         ENDO                                                           QUE00330
.*                                                                      QUE00340
         DO    '&NT$DEV'=''                                             QUE00350
&NT$DEV  SET   '0'                                                      QUE00360
         PNOTE '*','DEVICE ENTRY NOT SPECIFIED'                         QUE00370
         ENDO                                                           QUE00380
         ENTRY NT$DVC&NT$DEV                                            QUE00390
NT$DVC&NT$DEV EQU   *                                                   QUE00400
         DC    YL1(&NT$DEV)                                             QUE00410
.*                                                                      QUE00420
&FLG     SET   0                                                        QUE00430
         DO    1-('&NT$TYPF'='OUTPUT')                                  QUE00440
&FLG     SET   &FLG+32                                                  QUE00450
         DO    '&P(0)'='LOCQUE'                                         QUE00455
&FLG     SET   &FLG+128
         ENDO
         ENDO                                                           QUE00460
         DO    '&NT$CTRL'='YES'                                         QUE00470
&FLG     SET   &FLG+1                                                   QUE00480
         ENDO                                                           QUE00490
         DO    1-('&NT$VRBL'='YES')                                     QUE00500
&FLG     SET   &FLG+2                                                   QUE00510
         ENDO                                                           QUE00520
         DC    YL1(&FLG)                                                QUE00530
.*                                                                      QUE00540
         DO    '&NT$BKSZ'=''                                            QUE00550
         PNOTE '*','BLKSIZE NOT SPECIFIED'                              QUE00560
         DC    H'0'                                                     QUE00570
         GOTO  .B                                                       QUE00580
         ENDO                                                           QUE00590
         DC    H'&NT$BKSZ'                                              QUE00600
.B       LABEL                                                          QUE00610
.*                                                                      QUE00620
         DO    '&NT$NTRY'=''                                            QUE00630
         PNOTE '*','ENTRY POINT NOT SPECIFIED'                          QUE00640
         DC    F'0'                                                     QUE00650
         GOTO  .C                                                       QUE00660
         ENDO                                                           QUE00670
         DC    A(&NT$NTRY)                                              QUE00680
.C       LABEL                                                          QUE00690
.*                                                                      QUE00700
         DO    '&NT$EOFA'=''                                            QUE00710
         PNOTE '*','EOFADDR NOT SPECIFIED'                              QUE00720
         DC    F'0'                                                     QUE00730
         GOTO  .D                                                       QUE00740
         ENDO                                                           QUE00750
         DC    A(&NT$EOFA)                                              QUE00760
.D       LABEL                                                          QUE00770
.*                                                                      QUE00780
         DO    '&NT$LFD'=''                                             QUE00790
         PNOTE '*','LFD NAME NOT SPECIFIED'                             QUE00800
         DC    F'0'                                                     QUE00810
         GOTO  .E                                                       QUE00820
         ENDO                                                           QUE00830
         DC    A(&NT$LFD)                                               QUE00840
.E       LABEL                                                          QUE00850
.*                                                                      QUE00860
         DO    '&NT$FNCD'=''                                            QUE00870
         DC    XL1'04'                                                  QUE00880
         GOTO  .F                                                       QUE00890
         ENDO                                                           QUE00900
         DC    YL1(&NT$FNCD)                                            QUE00910
.F       LABEL                                                          QUE00920
.*                                                                      QUE00930
         DO    1-('&NT$TYPF'='OUTPUT')                                  QUE00940
         DO    '&NT$DEST'=''                                            QUE00950
         DC    XL1'0F'                                                  QUE00960
         GOTO  .G                                                       QUE00970
         ENDO                                                           QUE00980
         DC    XL1'&NT$DEST'                                            QUE00990
.G       LABEL                                                          QUE01000
.*                                                                      QUE01010
         DC    XL2'00'                                                  QUE01020
         GOTO  .END                                                     QUE01030
         ENDO                                                           QUE01040
         DC    XL3'00'                                                  QUE01050
.END     LABEL                                                          QUE01060
         DC    2F'0'                                                    QUE01070
         END                                                            QUE01080
